Panic!

Get me back to the home page!


Navigation

Skip to end of metadata
Go to start of metadata

 

 

An -based Project.

 

Project Overview

Responsible:

Formerly Responsible / Previous Projects:

Related Theses:

  • Mirko Wischer, Textuelle Darstellung und strukturbasiertes Editieren von Statecharts, February 2006 (pdf)
  • Özgün Bayramoglu, KIELER Infrastructure for Textual Modeling, December 2009 (pdf)
  • Christian Schneider, Integrating Graphical and Textual Modeling, February 2011 (pdf)

 

SCCharts are typically modeled using the textual SCT language defined as an Xtext grammar in KIELER. Generally, if you do not know which elements can be placed at a certain cursor position you are assisted by a content-assist that can be called pressing <Ctrl>+<Space>. It will display all possible valid elements also considering scoping of variables.

In the following we will demonstrate SCT using the famous ABRO example (the hello world of synchronous programming/modelling). We will then give details for modelling other SCCharts language constructs with SCT. For details on their semantics please be referred to  our PLDI paper [1].

[1] R. von Hanxleden, B. Duderstadt, C. Motika, S. Smyth, M. Mendler, J. Aguado, S. Mercer, and O. O’Brien. SCCharts: Sequentially Constructive Statecharts for Safety-Critical Applications. In Proc. ACM SIGPLAN Conference on Programming Language Design and Implementation (PLDI’14), Edinburgh, UK, June 2014. (pdf)

 

ABRO Example

In the following we will describe some basic elements using the famous ABRO example:

@HVLayout
scchart ABRO {
  input bool A, B, R;
  output bool O = false; 
  region Main:
  initial state ABO "ABthenO" {
    entry / O = false;
    initial state WaitAandB {
      region HandleA: 
      initial state wA 
      --> dA with A;
      final state dA;
      region HandleB:
      initial state wB
      --> dB with B;
      final state dB;
    }
    >-> done with / O = true;
    final state done;
  }
  o-> ABO with R;
}           

 

  1. In the first line you see how an SCChart is defined using the scchart keyword where the ID of the SCChart will be ABRO. An optional label can be inserted after ABRO using "<LABEL>".
  2. In the next three lines variables are declared, namely, A, B, R and O, where O is initialized with the value false. A, B, and R are inputs which must not be initialized and get there valued from the environment.
  3. An SCChart typically contains concurrent regions which are introduced with the keyword region as shown in Line 9.
  4. Every region must at least have one state, and every region must exactly have one initial state. An initial state ABO is defined for region Main in Line 6.
  5. Every state is terminated by a ; as shown in line 11 for state HandleA.
  6. If you like to specify internal behavior of a state, you can add concurrent regions to a state in { <regions> } as done for state ABO or state WaitAB.
  7. Transitions outgoing from a state must be declared right before a state is terminated with ;. For example a transition from state wA to state dA is declared in Line 11.
  8. Transitions can have triggers and effects which are separated by a dash: <trigger>/<effects>. Multiple sequential effects are separated by a ;. The transition in Line 11 declares just a trigger A (a dash is not necessary in this case), while the transition from line 18 declares only an effect O = true (here the dash is mandatory).
  9. There are three types of transitions: 1. normal/weak abort transitions -->,  2. strong abort transitions o-> and 3. termination/join transitions >->.

 

Detailed SCT Syntax of SCCharts Elements

SCChart, Initial State, State, Transition and Immediate Transition

Error rendering macro 'code': Invalid value specified for parameter 'lang'
 scchart StateTransition {
  initial state A
  --> B;
  state B
  --> C;
  state C
  --> A immediate;
}

 

 

Variable

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Variable {
  int var1;
  bool var2;
  int var3 = 3;
  bool var4 = false;
  input int var5;
  output float var6;
  input output bool var7;
  initial state A
  --> B;
  state B;
}

 

Transition: Trigger & Effect

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart TriggerEffect {
  input int var1;
  output bool var2;
  initial state A
  --> B with var1 == 3 / var2 = true;
  state B;
}

 

Super State

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart SuperState {
  initial state A
  --> B;
  state B {
    initial state B1
    --> B2;
    state B2;
  };
}

 

Super State: Final States & Termination Transition

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart FinalStateTermination {
  initial state A
  --> B;
  state B {
    initial state B1
    --> B2;
    final state B2;
  }
  >-> C;
  state C;
}

 

Super State: Weak Abort Transition

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart WeakAbort {
  input bool W;
  initial state A
  --> B;
  state B {
    initial state B1
    --> B2;
    state B2;
  }
  --> C with W;
  state C;
}

 

Super State: Strong Abort Transition

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart StrongAbort {
  input bool S;
  initial state A
  --> B;
  state B {
    initial state B1
    --> B2;
    state B2;
  }
  o-> C with S;
  
  state C;
}

 

Concurrent Regions (inside a Super State)

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Regions {
  input bool S;
  initial state A
  --> B;
  state B {
    region Region1 :
    initial state B1
    --> B2;
    state B2; region Region2 :
    initial state B3;
  };
}

 

Entry Action, During Action, Exit Action

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Actions {
  input bool var1;
  output bool var2;
  initial state A
  --> B;
  state B {
    entry var1 / var2 = true;
    during var1 / var2 = true;
    immediate during var1 / var2 = true;
    exit var1 / var2 = true;
    initial state B1
    --> B2;
    state B2;
  };
}

 

Shallow History Transition

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart HistoryShallow {
  input bool var1;
  output bool var2;
  initial state A
  --> B shallow history with var1;
  state B {
    initial state B1
    --> B2;
    state B2;
  }
  --> A with var1;
}

 

Deep History Transition

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart HistoryDeep {
  input bool var1;
  output bool var2;
  initial state A
  --> B history with var1;
  state B {
    initial state B1
    --> B2;
    state B2;
  }
  --> A with var1;
}

 

Deferred Transition

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Deferred {
  input bool var1;
  output bool var2;
  initial state A
  --> B deferred with var1;
  state B {
    entry var1 / var2 = true;
  }
  --> A with var1;
}

 

Transition with Count Delay

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart CountDelay {
  input bool var1;
  output bool var2;
  initial state A
  --> B with 4 var1;
  state B
  --> A with var1;
}

 

Array

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Array {
  int myArray[10][2];
    initial state init
  --> done with myArray[1][0] == 1 / myArray[2][1] = 2;
  final state done;
} 

 

Signal

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Signal {
  input signal i;
  output signal o
    initial state init
  --> done with i / o;
  final state done;
}  

 

Reference States

Important: To use the referenced SCCharts feature, activate the Xtext nature for your project!

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart MainSCChart {
  bool A[3];
  
  initial state S1 references InnerSCChart; 
}

scchart InnerSCChart  {
  input bool A[3];
  
  initial state S1
  --> S2 with A[0];
  
  final state S2;
} 

 


Annotations

The textual SCCharts language supports several annotations to influence the visual representation of the model.

Annotation are processed in sequential order.

PatternUsageDescriptionExample
@synthesis[<key>] <value>
Location:scchart
<key>The name of the synthesis option. The given name is evaluated case-insensitive and whitespace-ignoring. The options are searched for the first matching prefix.
<value>

The value type depends on the option type:

CheckBox: true or false

Choice: Name of choice item

Slider: Float value

Sets the synthesis option identified by <key> to the given value.

The available synthesis options for a diagram are displayed in the sidebar of the diagram view.

The values from the sidebar will be ignored if a corresponding annotation is present.

Error rendering macro 'code': Invalid value specified for parameter 'lang'
@diagram[paper] true
scchart Testing {
  initial state A
  --> B;
  final state B;
}
@layout[<key>] <value>
Location:scchart, state, region, transition
<key>The ID of the layout option. The options are searched for the first matching postfix.
<value>

The value type depends on the option type. The value is parsed case-sensitive.

Sets the layout property identified by <key> to the given value on the annotated element.

The available layout options are documented here.

Layout options will only affect the annotated element and no underlying hierarchy levels.

If a layout direction is specified with this annotation it overrides the layout direction set by HV-/VH-Layout in any parent element for this element.

Special case: If the direction is set on the scchart element (top level) it overrides the default alternating layout.

 Commonly Used
direction
Layout direction
priorityCan influence the order of regions
Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Testing {
    @layout[algorithm] de.cau.cs.kieler.graphviz.circo
    region:
    initial final state A
    --> B;
    state B
    --> C;
    state C
    --> A;
}

 

 

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Testing {
    @layout[direction] UP
    region "up":
    initial state A
    --> B;
    final state B;
    @layout[direction] LEFT
    region "left":
    initial state A
    --> B;
    final state B;
}

 

 

@HVLayout
@VHLayout
Location:scchart, state, region

Defines the order of the alternating layout directions.

The annotation can be mixed and nested in the SCChart and will only affect succeeding hierarchy levels.

The default is an implicit HVLayout starting at the top level state.

Error rendering macro 'code': Invalid value specified for parameter 'lang'
@VHLayout
scchart Testing {
  initial state A
  --> B;
  final state B;
}
@collapse
@expand
Location:region
The annotated region will be initially collapse or expanded.Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Testing {
  @collapsed  
  region:
  initial state A
  --> B;
  final state B;
}
@hide
Location:scchart, state, region, transition

The annotated element will be excluded from the diagram.

Transitions with a hidden source or target state will be hidden as well.

Error rendering macro 'code': Invalid value specified for parameter 'lang'
scchart Testing {
  initial state A
  --> B;
  @hide
  final state B;
}

 

Overview of Operators

The following briefly describes the operators that can be used in expressions.

Assignment OperatorDescriptionExample
=Assignment operatorx = 42
Arithmetic OperatorsDescriptionExample
+Addition2 + 1
-Subtraction2 - 1
*Multiplication3 * 2
:

Division

6 : 2
Unary OperatorDescriptionExample
+Indicate a positive number+2
-Negate a number-2
++
Increment
x++
--Decrementx--
Boolean OperatorDescriptionExample
==Equal tox == 2
!Negate a boolean value! (x == 2)
!=Not equal tox != 2
>Greater thanx > 2
>=Greather than or equal tox >= 2
<Less thanx < 2
<=Less than or equal tox <= 2
&&Conditional-ANDx > 0 && x < 9
||Conditional-ORx < 0 || x > 9
  • No labels