An -based Project.

SCCharts are typically modeled using the textual SCT language defined as an Xtext grammar in KIELER. Generally, if you do not know which elements can be placed at a certain cursor position you are assisted by a content-assist that can be called pressing <Ctrl>+<Space>. It will display all possible valid elements also considering scoping of variables.

In the following we will demonstrate SCT using the famous ABRO example (the hello world of synchronous programming/modelling). We will then give details for modelling other SCCharts language constructs with SCT. For details on their semantics please be referred to  our PLDI paper [1].

[1] R. von Hanxleden, B. Duderstadt, C. Motika, S. Smyth, M. Mendler, J. Aguado, S. Mercer, and O. O’Brien. SCCharts: Sequentially Constructive Statecharts for Safety-Critical Applications. In Proc. ACM SIGPLAN Conference on Programming Language Design and Implementation (PLDI’14), Edinburgh, UK, June 2014. (pdf)

ABRO Example

In the following we will describe some basic elements using the famous ABRO example:

scchart ABRO {
  input bool A;
  input bool B;
  input bool R;
  output bool O = false;
  region Main:
  initial state ABO {
    initial state WaitAB {
      region HandleA:
      initial state WA
      --> DA with A;
      final state DA;
      region HandleB:
      initial state WB
      --> DB with B;
      final state DB;
    }
    >-> Done with / O = true;
    state Done;
  }
  o-> ABO with R;
}            

1. In the first line you see how an SCChart is defined using the scchart keyword where the ID of the SCChart will be ABRO. An optional label can be inserted after ABRO using "<LABEL>".
2. In the next three lines variables are declared, namely, A, B, R and O, where O is initialized with the value false. A, B, and R are inputs which must not be initialized and get there valued from the environment.
3. An SCChart typically contains concurrent regions which are introduced with the keyword region as shown in Line 6.
4. Every region must at least have one state, and every region must exactly have one initial state. An initial state ABO is defined for region Main in Line 7.
5. Every state is terminated by a ; as shown in line 11 for state HandleA.
6. If you like to specify internal behavior of a state, you can add concurrent regions to a state in { <regions> } as done for state ABO or state WaitAB.
7. Transitions outgoing from a state must be declared right before a state is terminated with ;. For example a transition from state WA to state DA is declared in Line 11.
8. Transitions can have triggers and effects which are separated by a dash: <trigger>/<effects>. Multiple sequential effects are separated by a ;. The transition in Line 11 declares just a trigger A (a dash is not necessary in this case), while the transition from line 18 declares only an effect O = true (here the dash is mandatory).
9. There are three types of transitions: 1. normal/weak abort transitions -->,  2. strong abort transitions o-> and 3. termination/join transitions >->.

Detailed SCT Syntax of SCCharts Elements

SCChart, Initial State, State, Transition and Immediate Transition

 scchart StateTransition {
  initial state A
  --> B;
  state B
  --> C;
  state C
  --> A immediate;
}

Variable

scchart Variable {
  int var1;
  bool var2;
  int var3 = 3;
  bool var4 = false;
  input int var5;
  output float var6;
  input output bool var7;
  initial state A
  --> B;
  state B;
}

Transition: Trigger & Effect

scchart TriggerEffect {
  input int var1;
  output bool var2;
  initial state A
  --> B with var1 == 3 / var2 = true;
  state B;
}

Super State

scchart SuperState {
  initial state A
  --> B;
  state B {
    initial state B1
    --> B2;
    state B2;
  };
}

Super State: Final States & Termination Transition

scchart FinalStateTermination {
  initial state A
  --> B;
  state B {
    initial state B1
    --> B2;
    final state B2;
  }
  >-> C;
  state C;
}

Super State: Weak Abort Transition

scchart WeakAbort {
  input bool W;
  initial state A
  --> B;
  state B {
    initial state B1
    --> B2;
    state B2;
  }
  --> C with W;
  state C;
}

Super State: Strong Abort Transition

scchart StrongAbort {
  input bool S;
  initial state A
  --> B;
  state B {
    initial state B1
    --> B2;
    state B2;
  }
  o-> C with S;
  
  state C;
}

Concurrent Regions (inside a Super State)

scchart Regions {
  input bool S;
  initial state A
  --> B;
  state B {
    region Region1 :
    initial state B1
    --> B2;
    state B2; region Region2 :
    initial state B3;
  };
}

Entry Action, During Action, Exit Action

scchart Actions {
  input bool var1;
  output bool var2;
  initial state A
  --> B;
  state B {
    entry var1 / var2 = true;
    during var1 / var2 = true;
    immediate during var1 / var2 = true;
    exit var1 / var2 = true;
    initial state B1
    --> B2;
    state B2;
  };
}

Shallow History Transition

scchart HistoryShallow {
  input bool var1;
  output bool var2;
  initial state A
  --> B shallow history with var1;
  state B {
    initial state B1
    --> B2;
    state B2;
  }
  --> A with var1;
}

Deep History Transition

scchart HistoryDeep {
  input bool var1;
  output bool var2;
  initial state A
  --> B history with var1;
  state B {
    initial state B1
    --> B2;
    state B2;
  }
  --> A with var1;
}

Deferred Transition

scchart Deferred {
  input bool var1;
  output bool var2;
  initial state A
  --> B deferred with var1;
  state B {
    entry var1 / var2 = true;
  }
  --> A with var1;
}

Transition with Count Delay

scchart CountDelay {
  input bool var1;
  output bool var2;
  initial state A
  --> B with 4 var1;
  state B
  --> A with var1;
}

Array

scchart Array {
  int myArray[10][2];
    initial state init
  --> done with myArray[1][0] == 1 / myArray[2][1] = 2;
  final state done;
} 

Signal

scchart Signal {
  input signal i;
  output signal o
    initial state init
  --> done with i / o;
  final state done;
}